'*************************************************************************
'Script Name: Mathgame.vbs
'Author: Jerry Ford
'Created: 02/28/02
'Modified by:
'Modified date: 9/10/2008
'Mathmatical equation changed
'Description: This script prompts the user to solve a mathematical
'expression and demonstrates how to solve it in the event that the user
'cannot
'*************************************************************************

'Initialization Section

Option Explicit

Dim WshShl, QuestionOne, Proveit

'Define the title bar message to be displayed in the script's
'pop-up dialog
Const cTitlebarMsg = "The Math Game"

'Instantiate an instance of the WshShell object
Set WshShl = WScript.CreateObject("WScript.Shell")

'Present the player with the equation
QuestionOne = InputBox("What is the sum of 3 + 7 * 8 / 4 ?", cTitlebarMsg)

'See if the player provided an answer
If Len(QuestionOne) = 0 Then
  MsgBox "Sorry. You must enter a number to play this game."
  WScript.Quit
End If

'Make sure that the player typed a number
If IsNumeric(QuestionOne) <> True Then
  MsgBox "Sorry. You must enter a number to play this game."
  WScript.Quit
End If

'Check to see if the player provided the correct answer  
If QuestionOne = 17 Then
  MsgBox "Correct! You obviously know your math!"
Else
  ProveIt = MsgBox("Incorrect. Do you want to see me solve the " & _
  "equation?", 36, cTitlebarMsg)

  If ProveIt = 6 Then 'Player wants to see the solution
  
    'Start the WordPad application
    WshShl.Run "WordPad"

    'Pause script execution to give Windows enough time to load WordPad
    WScript.Sleep 2000

    'Use WordPad to show the player how to solve the equation

    WshShl.SendKeys "To answer this question you must follow the " & _
      "correct order of precedence when performing your calculations."

    WScript.Sleep 2000
    WshShl.SendKeys "~~"
    WshShl.SendKeys "1st, working from left to right multiply 7 * 8."
    WScript.Sleep 2000
    WshShl.SendKeys "~~"
    WshShl.SendKeys "2nd, divide the result by 4."
    WScript.Sleep 2000
    WshShl.SendKeys "~~"
    WshShl.SendKeys "3rd, add 3."
    WScript.Sleep 2000
    WshShl.SendKeys "~~"
    WshShl.SendKeys "The final answer is 17."
    WScript.Sleep 2000
    WshShl.SendKeys "~~"
    WshShl.SendKeys "~~"
    WshShl.SendKeys "In case you question my math..... watch this!"
    WScript.Sleep 2000
    WshShl.SendKeys "%{F4}"
    WshShl.SendKeys "%{N}"

    'Start the Calculator application
    WshShl.Run "Calc"

    'Use the Calculator application to solve the equation
    WScript.Sleep 2000
    WshShl.SendKeys 7 & "{*}"
    WScript.Sleep 2000
    WshShl.SendKeys 8
    WScript.Sleep 2000
    WshShl.SendKeys "~"
    WScript.Sleep 2000
    WshShl.SendKeys "{/}" & 4
    WScript.Sleep 2000
    WshShl.SendKeys "~"
    WScript.Sleep 2000
    WshShl.SendKeys "{+}" & 3
    WScript.Sleep 2000
    WshShl.SendKeys "~"
    WScript.Sleep 2000
    WshShl.SendKeys "%{F4}"
  End If
End If