Private Function FindDataLabels( _
        ByRef prngInspDataColLbls As Range, _
        ByRef pwksInspections As Worksheet _
            ) As Range

    ' ==========================================================================
    '
    ' Name:             FindDataLabels
    '
    ' Synopsis:         Using a list stored in a named range of another sheet,
    '                   locate the contiguous range of cells that contains the
    '                   column labels of the data.
    '
    ' Arguments:        prngInspDataColLbls = A Range object that represents a
    '                                         block of cells that contain, among
    '                                         other things, the column labels.
    '
    '                   pwksInspections     = A Worksheet object that represents
    '                                         the worksheet that contains the
    '                                         fire alarm inspection data.
    '
    ' Returns:          A Range object, containing the labels row of the fire
    '                   alarm inspection data.
    '
    ' Notes:            1)  Column 5 of range prngInspDataColLbls, identified in
    '                       the code by constant DATA_LABELS_TEXT_COLINDEX,
    '                       contains a list of columns, which are expected to be
    '                       in adjacent columns of the same row.
    '
    '                   2)  Sheet wksInspections is searched from the upper left
    '                       corner for the first label. The adjacent columns are
    '                       compared to the subsequent columns in the list. If
    '                       all appears to be in order, a range, starting at the
    '                       cell where the first label was found, and extending
    '                       for as many columns as there are rows in range
    '                       prngInspDataColLbls, is created and returned.
    '
    '                   3)  By returning a range object containing the entire
    '                       first row, this routine communicates both the origin
    '                       cell and the width of the intended data range to the
    '                       caller.
    '
    ' Author:           David A. Gray, Simple Soft Services, Inc., d/b/a WizardWrx
    '
    '                   This module was developed under contract to LifeProtection
    '                   Maintenance & Consulting, Inc. All copyright and other
    '                   ownership rights rest with the Contractor.
    '
    ' Copyright:        (C) 2008, LifeProtection Maintenance & Consulting, Inc.
    '                   Fort Worth, Texas, USA
    '                   http://lmcfire.com/
    '                   All rights reserved world wide.
    '
    ' References:
    '
    ' Created:          Thursday, 11 September 2008
    '
    ' Maintenance History
    '
    ' Date       Author Synopsis
    ' ---------- ------ --------------------------------------------------------
    ' 2008/09/11 DAG/WW Initial version created.
    ' ==========================================================================

    Const DATA_LABELS_TEXT_COLINDEX As Integer = 5
    Const DATA_LABELS_COL2_RESUME As Integer = 2

    On Error GoTo FindDataLabels_Err

    '   ------------------------------------------------------------------------
    '   If this happens, somebody has tampered with the control worksheets.
    '   ------------------------------------------------------------------------

    If prngInspDataColLbls.Columns.Count < DATA_LABELS_TEXT_COLINDEX Then
        mwwException.Throw ERR_NBR_INV_DATA_LABEL_RNG
    End If
    
    '   ------------------------------------------------------------------------
    '   Read the text of the first label from the control sheet. Quit if the
    '   cell is empty. If it is, somebody has tampered with the control sheet.
    '   ------------------------------------------------------------------------

    Dim strLabelText As String
    strLabelText = prngInspDataColLbls.Cells( _
        RANGE_ORIGIN_CELL_INDEX, _
        DATA_LABELS_TEXT_COLINDEX)

    If strLabelText = vbNullString Then
        mwwException.Throw ERR_NBR_INV_DATA_LABEL_RNG
    End If
    
    '   ------------------------------------------------------------------------
    '   The UsedRange property of a worksheet returns a Range that contains all
    '   the cells in the worksheet that have _ever_ been used, for anything.
    '
    '   Make sure it contains at least as many columns as there are rows defined
    '   in the control table. If not, the two have become out of sync.
    '   ------------------------------------------------------------------------

    Dim rngEverything As Range
    Set rngEverything = pwksInspections.UsedRange
    If rngEverything.Columns.Count < prngInspDataColLbls.Rows.Count Then
        mwwException.Throw ERR_NBR_COL_1_LABEL_NOT_FOUND
    End If

    '   ------------------------------------------------------------------------
    '   The Find method of the Range object enables us to do the same operation
    '   that we might perform in the UI. This is the most efficient way to find
    '   the first data column.
    '   ------------------------------------------------------------------------

    Dim rngCol1Cell As Range
    Set rngCol1Cell = rngEverything.Find( _
        strLabelText, _
        LookIn:=xlValues, _
        SearchOrder:=xlByRows, _
        SearchDirection:=xlNext, _
        MatchCase:=False)

    If rngCol1Cell Is Nothing Then
        mwwException.Throw ERR_NBR_COL_1_LABEL_NOT_FOUND
    End If

    '   ------------------------------------------------------------------------
    '   If all goes well, the Find method returns a Range object containing
    '   exactly one cell. The Row and Column properties of this cell give us the
    '   origin address of the data range, and, implicitly, the addresses of the
    '   remaining column label cells.
    '   ------------------------------------------------------------------------

    Dim lngCol1CellRow As Long
    Dim intCol1CellCol As Integer
    lngCol1CellRow = rngCol1Cell.Row
    intCol1CellCol = rngCol1Cell.Column

    Dim intCurrLabelRowIndex As Integer
    Dim intCurrDataColIndex As Integer
    intCurrDataColIndex = intCol1CellCol
    
    For intCurrLabelRowIndex = DATA_LABELS_COL2_RESUME To prngInspDataColLbls.Rows.Count
        strLabelText = prngInspDataColLbls.Cells( _
            intCurrLabelRowIndex, _
            DATA_LABELS_TEXT_COLINDEX)
        intCurrDataColIndex = intCurrDataColIndex + 1
        If strLabelText <> rngEverything.Cells(lngCol1CellRow, intCurrDataColIndex) Then
            mwwException.Throw _
                ERR_NBR_COL_LABELS_NOT_FOUND, _
                "Label for column " _
                    & intCurrLabelRowIndex _
                    & " cannot be found."
        End If
    
    Next intCurrLabelRowIndex

    Set FindDataLabels = rngCellsFromRng_P6C( _
        rngEverything, _
        lngCol1CellRow, _
        intCol1CellCol, _
        lngCol1CellRow, _
        intCol1CellCol + prngInspDataColLbls.Rows.Count - 1)

    Set rngEverything = Nothing

FindDataLabels_End:

    Exit Function

FindDataLabels_Err:

    mwwException.Show "FindDataLabels"
    Err.Raise mwwException.Number, _
              mwwException.Source, _
              mwwException.Description
    Exit Function   ' This is unreachable, but I leave it, for tiger proofing.

End Function

    Set rngCol1Cell = rngEverything.Find( _
        strLabelText, _
        LookIn:=xlValues, _
        SearchOrder:=xlByRows, _
        SearchDirection:=xlNext, _
        MatchCase:=False)

    Dim rngEverything As Range
    Set rngEverything = pwksInspections.UsedRange